SQL Server 触发器详情

 更新时间:2021-09-22 21:23:11   作者:佚名   我要评论(0)

目录1、什么是触发器2、 DML触发器分为2.1 after触发器(之后触发)2.2 instead of 触发器 (之前触发)3、 创建触发器3.1 创建insert类型触

1、什么是触发器

    触发器对表进行插入、更新、删除的时候会自动执行的特殊存储过程。触发器一般用在check约束更加复杂的约束上面。触发器和普通的存储过程的区别是:触发器是当对某一个表进行操作。诸如:updateinsertdelete这些操作的时候,系统会自动调用执行该表上对应的触发器。SQL Server 2005中触发器可以分为两类:DML触发器和DDL触发器,其中DDL触发器它们会影响多种数据定义语言语句而激发,这些语句有createalterdrop语句。

2、 DML触发器分为

2.1 after触发器(之后触发)

a、 insert触发器

b、 update触发器

c、 delete触发器

2.2 instead of 触发器 (之前触发)

其中after触发器要求只有执行某一操作insert、update、delete之后触发器才被触发,且只能定义在表上。而instead of触发器表示并不执行其定义的操作(insertupdatedelete)而仅是执行触发器本身。既可以在表上定义instead of触发器,也可以在视图上定义。

触发器有两个特殊的表:插入表(instered表)和删除表(deleted表)。这两张是逻辑表也是虚表。有系统在内存中创建者两张表,不会存储在数据库中。而且两张表的都是只读的,只能读取数据而不能修改数据。这两张表的结果总是与被改触发器应用的表的结构相同。当触发器完成工作后,这两张表就会被删除。Inserted表的数据是插入或是修改后的数据,而deleted表的数据是更新前的或是删除的数据。

对表的操作

Inserted逻辑表

Deleted逻辑表

增加记录(insert)

存放增加的记录

删除记录(delete)

存放被删除的记录

修改记录(update)

存放更新后的记录

存放更新前的记录

Update数据的时候就是先删除表记录,然后增加一条记录。这样在inserteddeleted表就都有update后的数据记录了。注意的是:触发器本身就是一个事务,所以在触发器里面可以对修改数据进行一些特殊的检查。如果不满足可以利用事务回滚,撤销操作。

3、 创建触发器

语法

create trigger tgr_name
on table_name
with encrypion –加密触发器
    for update...
as
    Transact-SQL

3.1 创建insert类型触发器

--创建insert插入类型触发器
if (object_id('tgr_classes_insert', 'tr') is not null)
    drop trigger tgr_classes_insert
go
create trigger tgr_classes_insert
on classes
    for insert --插入触发
as
    --定义变量
    declare @id int, @name varchar(20), @temp int;
    --在inserted表中查询已经插入记录信息
    select @id = id, @name = name from inserted;
    set @name = @name + convert(varchar, @id);
    set @temp = @id / 2;    
    insert into student values(@name, 18 + @id, @temp, @id);
    print '添加学生成功!';
go
--插入数据
insert into classes values('5班', getDate());
--查询数据
select * from classes;
select * from student order by id;

insert触发器,会在inserted表中添加一条刚插入的记录。

 3.2  创建delete类型触发器

--delete删除类型触发器
if (object_id('tgr_classes_delete', 'TR') is not null)
    drop trigger tgr_classes_delete
go
create trigger tgr_classes_delete
on classes
    for delete --删除触发
as
    print '备份数据中……';    
    if (object_id('classesBackup', 'U') is not null)
        --存在classesBackup,直接插入数据
        insert into classesBackup select name, createDate from deleted;
    else
        --不存在classesBackup创建再插入
        select * into classesBackup from deleted;
    print '备份数据成功!';
go
--
--不显示影响行数
--set nocount on;
delete classes where name = '5班';
--查询数据
select * from classes;
select * from classesBackup;
  

 delete触发器会在删除数据的时候,将刚才删除的数据保存在deleted表中。

 3.3  创建update类型触发器

--update更新类型触发器
if (object_id('tgr_classes_update', 'TR') is not null)
    drop trigger tgr_classes_update
go
create trigger tgr_classes_update
on classes
    for update
as
    declare @oldName varchar(20), @newName varchar(20);
    --更新前的数据
    select @oldName = name from deleted;
    if (exists (select * from student where name like '%'+ @oldName + '%'))
        begin
            --更新后的数据
            select @newName = name from inserted;
            update student set name = replace(name, @oldName, @newName) where name like '%'+ @oldName + '%';
            print '级联修改数据成功!';
        end
    else
        print '无需修改student表!';
go
--查询数据
select * from student order by id;
select * from classes;
update classes set name = '五班' where name = '5班';

update触发器会在更新数据后,将更新前的数据保存在deleted表中,更新后的数据保存在inserted表中。

 3.4 update更新列级触发器

if (object_id('tgr_classes_update_column', 'TR') is not null)
    drop trigger tgr_classes_update_column
go
create trigger tgr_classes_update_column
on classes
    for update
as
    --列级触发器:是否更新了班级创建时间
    if (update(createDate))
    begin
        raisError('系统提示:班级创建时间不能修改!', 16, 11);
        rollback tran;
    end
go
--测试
select * from student order by id;
select * from classes;
update classes set createDate = getDate() where id = 3;
update classes set name = '四班' where id = 7;

更新列级触发器可以用update是否判断更新列记录;

4、instead of类型触发器

instead of触发器表示并不执行其定义的操作(insertupdatedelete)而仅是执行触发器本身的内容。

创建语法:

create trigger tgr_name
on table_name
with encryption
    instead of update...
as
    T-SQL  

4.1 创建instead of触发器

if (object_id('tgr_classes_inteadOf', 'TR') is not null)
    drop trigger tgr_classes_inteadOf
go
create trigger tgr_classes_inteadOf
on classes
    instead of delete/*, update, insert*/
as
    declare @id int, @name varchar(20);
    --查询被删除的信息,病赋值
    select @id = id, @name = name from deleted;
    print 'id: ' + convert(varchar, @id) + ', name: ' + @name;
    --先删除student的信息
    delete student where cid = @id;
    --再删除classes的信息
    delete classes where id = @id;
    print '删除[ id: ' + convert(varchar, @id) + ', name: ' + @name + ' ] 的信息成功!';
go
--test
select * from student order by id;
select * from classes;
delete classes where id = 7;
   


4.2  显示自定义消息raiserror

if (object_id('tgr_message', 'TR') is not null)
    drop trigger tgr_message
go
create trigger tgr_message
on student
    after insert, update
as raisError('tgr_message触发器被触发', 16, 10);
go
--test
insert into student values('lily', 22, 1, 7);
update student set sex = 0 where name = 'lucy';
select * from student order by id;

4.3  修改触发器

alter trigger tgr_message
on student
after delete
as raisError('tgr_message触发器被触发', 16, 10);
go
--test
delete from student where name = 'lucy';

4.4 启用、禁用触发器

--禁用触发器
disable trigger tgr_message on student;
--启用触发器
enable trigger tgr_message on student;

4.5 查询创建的触发器信息

--查询已存在的触发器
select * from sys.triggers;
select * from sys.objects where type = 'TR';

--查看触发器触发事件
select te.* from sys.trigger_events te join sys.triggers t
on t.object_id = te.object_id
where t.parent_class = 0 and t.name = 'tgr_valid_data';

--查看创建触发器语句
exec sp_helptext 'tgr_message';

4.6 示例,验证插入数据

if ((object_id('tgr_valid_data', 'TR') is not null))
    drop trigger tgr_valid_data
go
create trigger tgr_valid_data
on student
after insert
as
    declare @age int,
            @name varchar(20);
    select @name = s.name, @age = s.age from inserted s;
    if (@age < 18)
    begin
        raisError('插入新数据的age有问题', 16, 1);
        rollback tran;
    end
go
--test
insert into student values('forest', 2, 0, 7);
insert into student values('forest', 22, 0, 7);
select * from student order by id;

4.7 示例,操作日志

if (object_id('log', 'U') is not null)
    drop table log
go
create table log(
    id int identity(1, 1) primary key,
    action varchar(20),
    createDate datetime default getDate()
)
go
if (exists (select * from sys.objects where name = 'tgr_student_log'))
    drop trigger tgr_student_log
go
create trigger tgr_student_log
on student
after insert, update, delete
as
    if ((exists (select 1 from inserted)) and (exists (select 1 from deleted)))
    begin
        insert into log(action) values('updated');
    end
    else if (exists (select 1 from inserted) and not exists (select 1 from deleted))
    begin
        insert into log(action) values('inserted');
    end
    else if (not exists (select 1 from inserted) and exists (select 1 from deleted))
    begin
        insert into log(action) values('deleted');
    end
go
--test
insert into student values('king', 22, 1, 7);
update student set sex = 0 where name = 'king';
delete student where name = 'king';
select * from log;
select * from student order by id;

到此这篇关于SQL Server 触发器详情的文章就介绍到这了,更多相关SQL Server 触发器内容请搜索脚本之家以前的文章或继续浏览下面的相关文章希望大家以后多多支持脚本之家!

您可能感兴趣的文章:
  • 关于喜忧参半的SQL Server触发器详解
  • 利用SQL Server触发器实现表的历史修改痕迹记录
  • SQLSERVER对加密的存储过程、视图、触发器进行解密(推荐)
  • SQL Server 使用触发器(trigger)发送电子邮件步骤详解
  • SQL Server实现用触发器捕获DML操作的会话信息【实例】
  • SQL Server:触发器实例详解
  • SqlServer触发器详解
  • SqlServer实现类似Oracle的before触发器示例
  • SQL SERVER中各类触发器的完整语法及参数说明
  • SQL SERVER 触发器介绍
  • SQL Server误区30日谈 第4天 DDL触发器就是INSTEAD OF触发器

相关文章

  • SQL Server 触发器详情

    SQL Server 触发器详情

    目录1、什么是触发器2、 DML触发器分为2.1 after触发器(之后触发)2.2 instead of 触发器 (之前触发)3、 创建触发器3.1 创建insert类型触
    2021-09-22
  • Python基础语法之容器详解

    Python基础语法之容器详解

    目录Python基础语法-容器1.列表(list)1.1 列表基本概念1.2 获取元素1.3 增、删、改1.3.1 增 - —增加元素1.3.2 删 — 删除元素1.3.3 改—改变
    2021-09-22
  • Python 绘制桑基图全面解析

    Python 绘制桑基图全面解析

    目录前言题目再现题目拆解创建桑基图添加桑基图选项返回桑基图绘制完成的对象3.完整源码总结&后记大家好,我是执念斩长河,一个刚刚学习pyth
    2021-09-22
  • 详解Golang五种原子性操作的用法

    详解Golang五种原子性操作的用法

    目录Go 语言提供了哪些原子操作 互斥锁跟原子操作的区别 比较并交换 atomic.Value保证任意值的读写安全 总结 本文我们详细聊一下Go语言
    2021-09-22
  • python Django的显示个人信息详解

    python Django的显示个人信息详解

    目录用命令创建Django项目1.将磁盘切换为D盘2.在D盘的路径下创建Django项目3.最后显示新建index文件夹启动项目1.输入以下命令启动项目2.在浏
    2021-09-22
  • C++中模板和STL介绍详解

    C++中模板和STL介绍详解

    目录一、模板1.1.函数模板1.1.1.两种函数模板的实例化1.1.2.模板参数的匹配原则1.2.类模板二、STL总结一、模板 对于一个交换函数,虽然C++支
    2021-09-22
  • python之tensorflow手把手实例讲解斑马线识别实现

    python之tensorflow手把手实例讲解斑马线识别实现

    一,斑马线的数据集 数据集的构成: test train zebra c
    2021-09-22
  • Java 数组迭代你会用吗

    Java 数组迭代你会用吗

    目录1、概述 2、通过循环进行数组迭代 3、JDK 8 之前使用老方式进行数组迭代 4、使用 Java 8 Stream 进行数组迭代 5、字符串的应用 6、
    2021-09-22
  • 解析spark源码yarn-cluster模式任务提交

    解析spark源码yarn-cluster模式任务提交

    目录一,运行命令二,任务提交流程图三,启动脚本四,程序入口类org.apache.spark.deploy.SparkSubmit五,org.apache.spark.deploy.yarn.Yar
    2021-09-22
  • 计算机网络传输协议TCP三次握手与四次挥手原理

    计算机网络传输协议TCP三次握手与四次挥手原理

    目录TCP三次握手四次挥手服务器状态转换客户端状态转换TCP状态转换图TCP中常见的面试题为什么是三次握手,不是一次或者两次为什么是三次握手
    2021-09-22

最新评论